Tek <tek### [at] evilsuperbraincom> wrote:
> But to layer clouds over a sky

... you don't put it on the sky_sphere. You should use eg. a horizontal
plane instead.

  The POV-Ray documentation gives a very bad example in one of its
tutorials about putting clouds on the sky_sphere itself. IMHO this bad
example should be fixed (and may perhaps even be).

  The reason why it's the incorrect way is that Earth clouds form a sphere
which center is not at the camera (as happens with sky_sphere), but
6000 km *below* the camera, the radius of the sphere being little larger
than that. In practice this means that from the point of view of the camera
the clouds form almost a plane in practice (even though it's strictly not
a plane, it is a good-enough approximation).
  If you put the coulds on the sky_sphere, the result will be completely
unrealistic and unnatural.

  Here is an example of how it can be done:

camera { location -z*2 look_at y*.5 angle 50 }
light_source { <1000, 2000, -500>, 1 }

sky_sphere
{ pigment
  { gradient y color_map
    { [0 rgb <.8,1,1>][.3 rgb <.2,.5,1>][1 rgb z]
    }
  }
}

plane
{ -y, -100
  pigment
  { bozo color_map
    { [0 rgb .5][.2 rgb 1][.5 rgbf 1]
    }
    turbulence .5
    scale 100
  }
  finish { ambient 1 }
}

// ground:
plane { y,-10 pigment { rgb <.8,.5,.3> } }


-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message